GetLoadGravity

Syntax

SapObject.SapModel.LinkElm.GetLoadGravity

VB6 Procedure

Function GetLoadGravity(ByVal Name As String, ByRef NumberItems As Long, ByRef LinkName() As String, ByRef LoadCase() As String, ByRef CSys() As String, ByRef x() As Double, ByRef y() As Double, ByRef z() As Double, Optional ByVal ItemType As eItemType = Object) As Long

Parameters

Name

The name of an existing link object, link element or group of objects, depending on the value of the ItemTypeElm item.

NumberItems

The total number of gravity loads retrieved for the specified link elements.

LinkName

This is an array that includes the name of the link element associated with each gravity load.

LoadCase

This is an array that includes the name of the coordinate system in which the gravity load multipliers are specified.

CSys

This is an array that includes the name of the coordinate system associated with each gravity load.

x, y, z

These are arrays of gravity load multipliers in the x, y and z directions of the specified coordinate system.

ItemTypeElm

This is one of the following items in the eItemTypeElm enumeration:

ObjectElm = 0

Element = 1

GroupElm = 2

SelectionElm = 3

If this item is ObjectElm, the load assignments are retrieved for the link elements corresponding to the link object specified by the Name item.

If this item is Element, the load assignments are retrieved for the link element specified by the Name item.

If this item is GroupElm, the load assignments are retrieved for the link elements corresponding to all link objects included in the group specified by the Name item.

If this item is SelectionElm, the load assignments are retrieved for link elements corresponding to all selected link objects, and the Name item is ignored.

Remarks

This function retrieves the gravity load assignments to link elements.

The function returns zero if the load assignments are successfully retrieved; otherwise it returns a nonzero value.

VBA Example

Sub GetLinkElmGravityLoad()
   'dimension variables
      Dim SapObject As Sap2000.SapObject
      Dim SapModel As cSapModel
      Dim ret As Long
      Dim NumberItems As Long
      Dim LinkName() As String
      Dim LoadCase() As String
      Dim CSys() As String
      Dim x() As Double
      Dim y() As Double
      Dim z() As Double
      Dim Name1 As String
      Dim Name2 As String

   'create Sap2000 object
      Set SapObject = New SAP2000.SapObject

   'start Sap2000 application
      SapObject.ApplicationStart

   'create SapModel object
      Set SapModel = SapObject.SapModel

   'initialize model
      ret = SapModel.InitializeNewModel

   'create model from template
      ret = SapModel.File.New2DFrame(PortalFrame, 2, 144, 2, 288)

   'add link object by points
      ret = SapModel.LinkObj.AddByPoint("3", "", Name1, True)
      ret = SapModel.LinkObj.AddByPoint("1", "5", Name2)

   'refresh view
      ret = SapModel.View.RefreshView

   'assign link object gravity loads
      ret = SapModel.LinkObj.SetLoadGravity("ALL", "DEAD", 0, 0, -1, , , Group)

   'create the analysis model
      ret = SapModel.Analyze.CreateAnalysisModel

   'get link element gravity load
      ret = SapModel.LinkElm.GetLoadGravity("ALL", NumberItems, LinkName, LoadCase, CSys, x, y, z, GroupElm)

   'close Sap2000
      SapObject.ApplicationExit False
      Set SapModel = Nothing
      Set SapObject = Nothing
End Sub

Release Notes

Initial release in version 11.00.