www.kxcad.net Home > CAE Index > ANSYS Index > Release 11.0 Documentation for ANSYS

A circuit consists of two resistors, and inductor, an independent voltage source, an independent current source, and a current-controlled current source. Determine the voltage at node 4 in the circuit (Refer to the figure below).

You can perform the example AC (harmonic) circuit analysis using the ANSYS commands shown below instead of GUI choices. Items prefaced with an exclamation point (!) are comments.

/BATCH,LIST
/PREP7
/TITLE, AC CIRCUIT ANALYSIS
/COM,   SEE SCHAUMS OUTLINE "BASIC CIRCUIT ANALYSIS", 2ND ED, 1992,
/NOPR
ET,1,CIRCU124,4    ! VOLTAGE SOURCE
ET,2,CIRCU124,3    ! CURRENT SOURCE
ET,3,CIRCU124,0    ! RESISTOR 
ET,4,CIRCU124,1    ! INDUCTOR
ET,5,CIRCU124,12   ! CURRENT CONTROLLED CURRENT SOURCE

R,1,15,30          ! VOLTAGE SOURCE
R,2,5,-45          ! CURRENT SOURCE
R,3,3              ! R1
R,4,2              ! R2
R,5,4              ! L1
R,6,-3              ! CCCS GAIN

N,1
NGEN,10,1,1,1,1

TYPE,1
REAL,1
E,2,1,7            ! V1
TYPE,3
REAL,3
E,2,3              ! R1
TYPE,4
REAL,5
E,3,1              ! L1
TYPE,3
REAL,4
E,3,4              ! R2
TYPE,5
REAL,6   
E,3,4,5,2,1,7      ! CCCS
TYPE,2
REAL,2
E,1,4              ! C1

FINISH
/SOLU
ANTYP,HARM
D,1,VOLT,0
PI=4*ATAN(1)
HARFRQ,1/(2*PI)
OUTPR,ALL,ALL
HROUT,OFF
SOLVE
FINISH

/POST1
SET,1,1                 ! READ IN REAL SOLUTION
PRESOL,ELEM             ! PRINT CIRCUIT SOLUTION PER ELEMENT
SET,1,1,,1              ! READ IN IMAGINARY SOLUTION
PRESOL,ELEM             ! PRINT CIRCUIT SOLUTION PER ELEMENT
FINISH

Target Solution, Node 4: V = 14.44 -j 1.41