3.3. Sample Thermal-Stress Analysis of a Thick-walled Cylinder (Batch or Command Method)

www.kxcad.net Home > CAE Index > ANSYS Index > Release 11.0 Documentation for ANSYS



3.3.1. Problem Description

A thick-walled cylinder is maintained at a temperature Ti on the inner surface and To on the outer surface. The temperature distribution in the cylinder and the axial and hoop stresses at the inner surface are determined. See Verification Manual problem VM32 Thermal Stresses in a Long Cylinder for a similar problem.

A quarter-cylinder model is chosen to demonstrate the thermal-stress analysis using a dissimilar mesh between the thermal and structural models. SOLID87 elements model the thermal response while SOLID95 elements model the structural response.

The thermal model is constructed first. Temperature constraints are applied to the inner and outer surface. The structural model is constructed next. Constraints are applied to simulate symmetry boundary conditions. In the z-direction, one face is constrained while the other face has the UZ degree of freedom for the nodes coupled to simulate an infinitely long cylinder.

A volumetric load transfer flag is set for all the elements since the mesh for the thermal and structural models completely overlap.

In the solution phase, the model is set up to use the ANSYS Multi-field solver (MFANALYSIS). The thermal analysis is identified as field #1, assigning the thermal element type to that field (MFELEM). In a similar fashion, the structural analysis is identified as field #2 with the structural element type assigned to that field. Since this is a static analysis, the time is set to 1.0 (MFITER) with a single time increment (MFDTIME). Relaxation of the transferred load quantities is set to 0.5 (MFRELAX).

Field file names are assigned which will be used in the naming of the results files (MFFNAME). A volumetric load transfer is defined which will send temperatures from the thermal field to the structural field (MFVOLUME). Analysis options are set for the thermal solution and written to a command file (MFCMMAND). Similarly, analysis options are set for the structural solution and written to a command file. The solution is then performed.

The following figure illustrates the thermal and structural mesh.

Figure 3.20  Thermal and Structural Model Mesh

3.3.2. Results

The following figure illustrates the thermal solution and the axial stress.

Figure 3.21  Temperature Profile and Axial Stress

The analytic solution for both the hoop and axial stress is 420.24 at the inner cylinder wall. The ANSYS results are shown in the following table.

Table 3.4  Hoop and Axial Stress Variation

Stress ComponentMin ValueMax Value
Hoop Stress418.3418.9
Axial Stress421.5421.7

3.3.3. Command Listing

The command listing below demonstrates the problem input. Text prefaced by an exclamation point (!) is a comment.

/batch,list
/TITLE, Thermal stress analysis of a long thick cylinder
/com,   Reference: Verification Manual Problem VM32
/com,
/com,****************** Characteristics *******************************
/com,
/com, Thermal Element:     SOLID87
/com, Structural Element:  SOLID95 
/com,
/com,******************** Expected results ****************************
/com, 
/com, At inner radius:  Axial and hoop stress = 420.42
/com,
/com,******************************************************************
/com,

ir=.1875                    ! Cylinder inner radius
or=.625                     ! Cylinder outer radius
theta=90                    ! Angle for partial cylinder model
h=.5

/prep7
! Thermal model
et,1,87                     ! Thermal element type
mp,kxx,1,3                  ! Conductivity
cylind,ir,or,0,h,0,theta    ! Build thermal model
esiz,,6
vmesh,all                   ! Free tetrahedral mesh      
csys,1
nsel,s,loc,x,ir
d,all,temp,-1               ! Set inner wall temperature
nsel,s,loc,x,or
d,all,temp,0                ! Set outer wall temperature
allsel,all
! Structure Model
et,2,95                     ! Structural element type
mp,ex,2,30E6                ! Structural properties 
mp,alpx,2,1.435E-5
mp,nuxy,2,.3
cylind,ir,or,0,h,0,theta    ! Build structural model
esiz,,9
vatt,2,1,2
vmesh,all                   ! Mapped brick mesh
csys,0
esel,s,type,,2
nsle
nsel,r,loc,z
d,all,uz,0                  ! Set structural bc's
nsle
nsel,r,loc,z,h
cp,1,uz,all
nsle
nsel,r,loc,y
d,all,uy,0
nsle
nsel,r,loc,x
d,all,ux,0
allsel,all
bfe,all,fvin,,1             ! Volumetric Flag for load transfer  
finish
/solu    
mfan,on                     ! Activate MFS analysis
mfel,1,1                    ! Field #1: Thermal
mfel,2,2                    ! Field #2: Structure
mfor,1,2                    ! Field order (thermal, structure)
mfti,1                      ! Time at end of analysis
mfdt,1                      ! One field loop within a stagger
mfit,5                      ! Max 5 stagger loops
mfre,all,0.5                ! Field transfer relaxation parameter
mffn,1,therm1               ! Field #1 filename
mffn,2,struc2               ! Field #2 filename
mfvo,1,1,temp,2             ! Volumetric load transfer (temp to structure)
antyp,stat
eqslv,iccg  
mfcm,1                      ! Write thermal analysis options
antype,static
eqslv,pcg         
mfcm,2                      ! Write structure analysis options
solve
finish

/post1
file,therm1,rth             ! Thermal results file
set,last
esel,s,type,,1              ! Select thermal elements
plns,temp                   ! Plot temperatures
finish

/post1
file,struc2,rst             ! Structure field results file
set,last
esel,s,type,,2              ! Select structural elements
rsys,1                      ! set result for cylindrical c.s.
csys,1
nsel,s,loc,x,ir             ! select nodes at inner radius
nsort,s,z                   ! sort z-stress
*get,szmax,sort,,max        ! get max and min values
*get,szmin,sort,,min
nsort,s,y                   ! sort hoop stress 
*get,symax,sort,,max        ! get max and min values
*get,symin,sort,,min
*status                     ! show max/min values
nsel,all
plns,s,z                    ! Plot z-axis stress 
finish